Scelta ponderata casuale in T-SQL

La risposta di Dane include un sé che si unisce in un modo che introduce una legge quadrata. (n*n/2) righe dopo il join dove ci sono n righe nella tabella.

L'ideale sarebbe poter analizzare la tabella solo una volta.

DECLARE @id int, @weight_sum int, @weight_point int
DECLARE @table TABLE (id int, weight int)

INSERT INTO @table(id, weight) VALUES(1, 50)
INSERT INTO @table(id, weight) VALUES(2, 25)
INSERT INTO @table(id, weight) VALUES(3, 25)

SELECT @weight_sum = SUM(weight)
FROM @table

SELECT @weight_point = FLOOR(((@weight_sum - 1) * RAND() + 1))

SELECT
    @id = CASE WHEN @weight_point < 0 THEN @id ELSE [table].id END,
    @weight_point = @weight_point - [table].weight
FROM
    @table [table]
ORDER BY
    [table].Weight DESC

Questo passerà attraverso la tabella, impostando @id all'id di ogni record valore mentre allo stesso tempo decrementa @weight punto. Alla fine, il @weight_point andrà in negativo. Ciò significa che il SUM di tutti i pesi precedenti è maggiore del valore target scelto casualmente. Questo è il record che vogliamo, quindi da quel momento in poi impostiamo @id a se stesso (ignorando eventuali ID nella tabella).

Questo viene eseguito attraverso la tabella solo una volta, ma deve essere eseguito attraverso l'intera tabella anche se il valore scelto è il primo record. Poiché la posizione media è a metà della tabella (e inferiore se ordinata per peso crescente), scrivere un loop potrebbe essere più veloce... (soprattutto se le ponderazioni sono in gruppi comuni):

DECLARE @id int, @weight_sum int, @weight_point int, @next_weight int, @row_count int
DECLARE @table TABLE (id int, weight int)

INSERT INTO @table(id, weight) VALUES(1, 50)
INSERT INTO @table(id, weight) VALUES(2, 25)
INSERT INTO @table(id, weight) VALUES(3, 25)

SELECT @weight_sum = SUM(weight)
FROM @table

SELECT @weight_point = ROUND(((@weight_sum - 1) * RAND() + 1), 0)

SELECT @next_weight = MAX(weight) FROM @table
SELECT @row_count   = COUNT(*)    FROM @table WHERE weight = @next_weight
SET @weight_point = @weight_point - (@next_weight * @row_count)

WHILE (@weight_point > 0)
BEGIN
    SELECT @next_weight = MAX(weight) FROM @table WHERE weight < @next_weight
    SELECT @row_count   = COUNT(*)    FROM @table WHERE weight = @next_weight
    SET @weight_point = @weight_point - (@next_weight * @row_count)
END

-- # Once the @weight_point is less than 0, we know that the randomly chosen record
-- # is in the group of records WHERE [table].weight = @next_weight

SELECT @row_count = FLOOR(((@row_count - 1) * RAND() + 1))

SELECT
    @id = CASE WHEN @row_count < 0 THEN @id ELSE [table].id END,
    @row_count = @row_count - 1
FROM
    @table [table]
WHERE
    [table].weight = @next_weight
ORDER BY
    [table].Weight DESC