Suddivisione dei valori delimitati in una colonna SQL in più righe

Se utilizzi SQL Server 2016+

Puoi utilizzare il nuovo STRING_SPLIT funzione, di cui ho scritto sul blog qui, e Brent Ozar ha scritto sul blog qui.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Se utilizzi ancora una versione precedente a SQL Server 2016

Crea una funzione di divisione. Questo è solo uno dei tanti esempi disponibili:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Ne ho discussi alcuni altri qui, qui, e un approccio migliore rispetto alla divisione in primo luogo qui.

Ora puoi estrapolare semplicemente:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Inoltre suggerisco di non mettere i trattini nei nomi delle colonne. Significa che devi sempre metterli tra [square brackets] .