Oracle:esiste un modo per ottenere errori di sintassi SQL recenti?

Puoi creare un trigger in Oracle che registrerà tutti gli errori (o praticamente tutti - NO_DATA_FOUND non è considerato un errore). Nell'esempio seguente, qualsiasi errore nello schema viene registrato nella tabella TRACK_DETAIL (errore in una riga, SQL non riuscito nella successiva). Puoi renderlo più sofisticato con un numero di sequenza, data/ora ecc.

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

Ricorda di rilasciare (o disabilitare) il trigger quando hai finito con esso.