Questo è un po 'complicato, ma è certamente possibile.
Iniziamo calcolando il rilevamento da un punto all'altro. Dato un punto di partenza, un rilevamento e una distanza, la seguente funzione restituirà il punto di destinazione:
CREATE FUNCTION [dbo].[func_MoveTowardsPoint](@start_point geography,
@end_point geography,
@distance int) /* Meters */
RETURNS geography
AS
BEGIN
DECLARE @ang_dist float = @distance / 6371000.0; /* Earth's radius */
DECLARE @bearing decimal(18,15);
DECLARE @lat_1 decimal(18,15) = Radians(@start_point.Lat);
DECLARE @lon_1 decimal(18,15) = Radians(@start_point.Long);
DECLARE @lat_2 decimal(18,15) = Radians(@end_point.Lat);
DECLARE @lon_diff decimal(18,15) = Radians(@end_point.Long - @start_point.Long);
DECLARE @new_lat decimal(18,15);
DECLARE @new_lon decimal(18,15);
DECLARE @result geography;
/* First calculate the bearing */
SET @bearing = ATN2(sin(@lon_diff) * cos(@lat_2),
(cos(@lat_1) * sin(@lat_2)) -
(sin(@lat_1) * cos(@lat_2) *
cos(@lon_diff)));
/* Then use the bearing and the start point to find the destination */
SET @new_lat = asin(sin(@lat_1) * cos(@ang_dist) +
cos(@lat_1) * sin(@ang_dist) * cos(@bearing));
SET @new_lon = @lon_1 + atn2( sin(@bearing) * sin(@ang_dist) * cos(@lat_1),
cos(@ang_dist) - sin(@lat_1) * sin(@lat_2));
/* Convert from Radians to Decimal */
SET @new_lat = Degrees(@new_lat);
SET @new_lon = Degrees(@new_lon);
/* Return the geography result */
SET @result =
geography::STPointFromText('POINT(' + CONVERT(varchar(64), @new_lon) + ' ' +
CONVERT(varchar(64), @new_lat) + ')',
4326);
RETURN @result;
END
Capisco che hai bisogno di una funzione che accetta una stringa lineare come input, non solo i punti di inizio e fine. Il punto deve muoversi lungo un percorso di segmenti di linea concatenati e deve continuare a muoversi attorno agli "angoli" del percorso. All'inizio potrebbe sembrare complicato, ma penso che possa essere affrontato come segue:
- Esegui l'iterazione in ogni punto della stringa di linea con
STPointN(), da x=1 a x=STNumPoints(). - Trova la distanza con
STDistance()tra il punto corrente nell'iterazione al punto successivo:@linestring.STPointN(x).STDistance(@linestring.STPointN(x+1)) -
Se la distanza sopra> la distanza di input 'n':
...quindi il punto di destinazione è tra questo punto e il successivo. Basta applicare
func_MoveTowardsPointpunto di passaggio x come punto iniziale, punto x+1 come punto finale e distanza n. Restituisci il risultato e interrompi l'iterazione.Altro:
...il punto di destinazione è più lontano nel percorso dal punto successivo nell'iterazione. Sottrai la distanza tra il punto x e il punto x+1 dalla tua distanza 'n'. Continua l'iterazione con la distanza modificata.
Potresti aver notato che possiamo facilmente implementare quanto sopra in modo ricorsivo, anziché in modo iterativo.
Facciamolo:
CREATE FUNCTION [dbo].[func_MoveAlongPath](@path geography,
@distance int,
@index int = 1)
RETURNS geography
AS
BEGIN
DECLARE @result geography = null;
DECLARE @num_points int = @path.STNumPoints();
DECLARE @dist_to_next float;
IF @index < @num_points
BEGIN
/* There is still at least one point further from the point @index
in the linestring. Find the distance to the next point. */
SET @dist_to_next = @path.STPointN(@index).STDistance(@path.STPointN(@index + 1));
IF @distance <= @dist_to_next
BEGIN
/* @dist_to_next is within this point and the next. Return
the destination point with func_MoveTowardsPoint(). */
SET @result = [dbo].[func_MoveTowardsPoint](@path.STPointN(@index),
@path.STPointN(@index + 1),
@distance);
END
ELSE
BEGIN
/* The destination is further from the next point. Subtract
@dist_to_next from @distance and continue recursively. */
SET @result = [dbo].[func_MoveAlongPath](@path,
@distance - @dist_to_next,
@index + 1);
END
END
ELSE
BEGIN
/* There is no further point. Our distance exceeds the length
of the linestring. Return the last point of the linestring.
You may prefer to return NULL instead. */
SET @result = @path.STPointN(@index);
END
RETURN @result;
END
Con quello in atto, è il momento di fare alcuni test. Usiamo la stringa di linea originale fornita nella domanda e richiederemo i punti di destinazione a 350m, a 3500m ea 7000m:
DECLARE @g geography;
SET @g = geography::STGeomFromText('LINESTRING(-122.360 47.656,
-122.343 47.656,
-122.310 47.690)', 4326);
SELECT [dbo].[func_MoveAlongPath](@g, 350, DEFAULT).ToString();
SELECT [dbo].[func_MoveAlongPath](@g, 3500, DEFAULT).ToString();
SELECT [dbo].[func_MoveAlongPath](@g, 7000, DEFAULT).ToString();
Il nostro test restituisce i seguenti risultati:
POINT (-122.3553270591861 47.6560002502638)
POINT (-122.32676470116748 47.672728464582583)
POINT (-122.31 47.69)
Si noti che l'ultima distanza richiesta (7000 m) ha superato la lunghezza della linea, quindi ci è stato restituito l'ultimo punto. In questo caso, puoi facilmente modificare la funzione per restituire NULL, se preferisci.
