La funzione tabella con raccolta in blocco genera un tipo di dati non valido

Stai tentando di utilizzare tipi a livello di pacchetto in SQL semplice, il che non è consentito. I tipi dichiarati nel pacchetto non sono visibili o validi al di fuori di PL/SQL (o anche in semplici istruzioni SQL all'interno di PL/SQL). Una versione ridotta di ciò che stai facendo:

create or replace package types as
    type my_rec_type is record (dummy dual.dummy%type);
    type my_table_type is table of my_rec_type index by binary_integer;
end types;
/

create or replace package p42 as
    function get_table return types.my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return types.my_table_type is
        my_table types.my_table_type;
    begin
        select * bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

SQL Error: ORA-00902: invalid datatype

Anche all'interno del pacchetto, se si disponesse di una procedura che tentasse di utilizzare la funzione tabella, si verificherebbe un errore. Se hai aggiunto:

    procedure test_proc is
    begin
        for r in (select * from table(get_table)) loop
            null;
        end loop;
    end test_proc;

... la compilazione del corpo del pacchetto fallirebbe con ORA-22905: cannot access rows from a non-nested table item .

È necessario dichiarare i tipi a livello di schema, non in un pacchetto, quindi utilizzando SQL create type comando :

create type my_obj_type is object (dummy varchar2(1));
/

create type my_table_type is table of my_obj_type;
/

create or replace package p42 as
    function get_table return my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return my_table_type is
        my_table my_table_type;
    begin
        select my_obj_type(dummy) bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

DUMMY
-----
X