Valore CLOB in uscita/ritorno da plsql (localizzatore LOB non valido specificato:ORA-22275)

A questo punto:

    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob

... il tuo l_clob Il parametro OUT non è stato inizializzato. Anche renderlo un CLOB vuoto non funziona (quindi anche se hai creato l_clob un parametro IN OUT si lamenterebbe ancora) come documentazione per empty_clob menzioni :

Puoi invece utilizzare un CLOB temporaneo, aggiungendo una chiamata a dbms_lob.createtemporary(l_clob, true) prima di provare ad usarlo:

...
begin
    l_bfile := bfilename( 'SCHEMES_OF_PS', p_file_name );
    dbms_lob.fileopen( l_bfile );
    dbms_lob.createtemporary(l_clob, true);
    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob
      ...

E quindi non è necessario fornire un valore iniziale vuoto quando lo chiami:

declare
  myVal clob;
begin
  dbst_load_a_file('Konotop.svg', myVal);
  DBMS_OUTPUT.PUT_LINE(myVal);
end;
/

Funziona anche come funzione:

create or replace 
function dbst_load_a_file( p_file_name in varchar2) return clob
as
    l_clob    clob;
    l_bfile   bfile;
    dst_offset  number := 1 ;
    src_offset  number := 1 ;
    lang_ctx    number := DBMS_LOB.DEFAULT_LANG_CTX;
    warning     number;
begin
    l_bfile := bfilename( 'SCHEMES_OF_PS', p_file_name );
    dbms_lob.fileopen( l_bfile );
    dbms_lob.createtemporary(l_clob, true);
    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob
    , SRC_BFILE    => l_bfile
    , AMOUNT       => dbms_lob.getlength( l_bfile )
    , DEST_OFFSET  => dst_offset
    , SRC_OFFSET   => src_offset
    , BFILE_CSID   => DBMS_LOB.DEFAULT_CSID
    , LANG_CONTEXT => lang_ctx
    , WARNING      => warning);
    dbms_lob.fileclose( l_bfile );
    return l_clob;
end;
/

select dbst_load_a_file('Konotop.svg') from dual;

Oppure usa in un insert come nella tua domanda modificata.