Questo è davvero un argomento più ampio, ma questo è l'approccio che penso sia più facile da implementare e funzioni bene. Il trucco è utilizzare SQL dinamico, ma implementarlo in modo da passare sempre lo stesso numero di parametri (necessari) E consentire a Oracle di cortocircuitare quando non si dispone di un valore per un parametro (quello che ti manca il tuo approccio attuale). Ad esempio:
set serveroutput on
create or replace procedure test_param(p1 in number default null, p2 in varchar2 default null) as
l_sql varchar2(4000);
l_cur sys_refcursor;
l_rec my_table%rowtype;
l_ctr number := 0;
begin
l_sql := 'select * from my_table where 1=1';
if (p1 is not null) then
l_sql := l_sql || ' and my_num_col = :p1';
else
-- short circuit for optimizer (1=1)
l_sql := l_sql || ' and (1=1 or :p1 is null)';
end if;
if (p2 is not null) then
l_sql := l_sql || ' and name like :p2';
else
-- short circuit for optimizer (1=1)
l_sql := l_sql || ' and (1=1 or :p2 is null)';
end if;
-- show what the SQL query will be
dbms_output.put_line(l_sql);
-- note always have same param list (using)
open l_cur for l_sql using p1,p2;
-- could return this cursor (function), or simply print out first 10 rows here for testing
loop
l_ctr := l_ctr + 1;
fetch l_cur
into l_rec;
exit when l_cur%notfound OR l_ctr > 10;
dbms_output.put_line('Name is: ' || l_rec.name || ', Address is: ' || l_rec.address1);
end loop;
close l_cur;
end;
Per testare, eseguilo semplicemente. Ad esempio:
set serveroutput on
-- using 0 param
exec test_param();
-- using 1 param
exec test_param(123456789);
-- using 2 params
exec test_param(123456789, 'ABC%');
Sul mio sistema, la tabella utilizzata è di oltre 100 mm di righe con un indice nel campo del numero e nel campo del nome. Restituisce quasi istantaneamente. Nota anche che potresti non voler selezionare * se non hai bisogno di tutte le colonne, ma sono un po' pigro e sto usando %rowtype per questo esempio.
Spero di esserti stato d'aiuto
