Come minimo, devi interrogare ALL_TAB_COLUMNS, non ALL_TABLES
DECLARE
match_count integer;
v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN
FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP
EXECUTE IMMEDIATE
'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
' WHERE '||t.column_name||' = :1'
INTO match_count
USING v_search_string;
IF match_count > 0 THEN
dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
END IF;
END LOOP;
END;
/
Se stai cercando una stringa, tuttavia, quasi sicuramente vorrai limitarti a cercare colonne che potrebbero memorizzare una stringa. Non avrebbe senso, ad esempio, cercare una stringa in una colonna DATE. E a meno che tu non abbia una grande conoscenza a priori di cosa contiene una colonna BLOB e la possibilità di analizzare la formattazione binaria della colonna BLOB, non avrebbe senso cercare una stringa in una colonna BLOB. Detto questo, sospetto che tu voglia qualcosa di più simile a
DECLARE
match_count integer;
v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN
FOR t IN (SELECT owner,
table_name,
column_name
FROM all_tab_columns
WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2',
'CLOB', 'NCLOB') )
LOOP
BEGIN
EXECUTE IMMEDIATE
'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
' WHERE '||t.column_name||' = :1'
INTO match_count
USING v_search_string;
IF match_count > 0 THEN
dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
END IF;
EXCEPTION
WHEN others THEN
dbms_output.put_line( 'Error encountered trying to read ' ||
t.column_name || ' from ' ||
t.owner || '.' || t.table_name );
END;
END LOOP;
END;
/
Ovviamente, questo sarà follemente lento:avresti scansionato completamente ogni tabella una volta per ogni colonna di stringa nella tabella. Con tabelle di dimensioni moderatamente grandi e un numero moderato di colonne di stringhe, è probabile che ci vorrà un po' di tempo.
