Come verificare se il file è un'immagine utilizzando PL/SQL?

In questo post del blog, condivido una funzione con la quale puoi verificare se un file è un file immagine o non utilizza PL/SQL. Il programma verificherà il file leggendone l'intestazione e non il nome dell'estensione del file. Attualmente, la funzione può identificare tre tipi di immagini che sono JPG, PNG e GIF.

Funzione PL/SQL per verificare se il file è un file immagine

La seguente funzione PL/SQL leggerà l'intestazione del file e quindi restituirà il tipo di immagine nel tipo di dati varchar2. La funzione get_image_type accetta due argomenti e sono i seguenti:

1. Oggetto Oracle Directory (come i_dir) Scopri come creare un oggetto directory Oracle.
2. Nome file (come i_file) dovrebbe esistere nella directory.

CREATE OR REPLACE FUNCTION get_image_type (i_dir    IN VARCHAR2,
                                           i_file   IN VARCHAR2)
   RETURN VARCHAR2
AS
   l_bfile       BFILE;
   l_blob        BLOB;
   l_file_type   VARCHAR2 (50);
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   IF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 8, 1)) = '89504E470D0A1A0A'
   THEN
      l_file_type := 'PNG';
   ELSIF DBMS_LOB.SUBSTR (l_blob, 3, 1) = '474946'
   THEN
      l_file_type := 'GIF';
   ELSIF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 3, 1)) = 'FFD8FF'
   THEN
      l_file_type := 'JPG';
   ELSE
      l_file_type := 'The file is not an image.';
   END IF;

   RETURN l_file_type;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RETURN 'The file does not exists.';
END get_image_type;

Test

Nel programma PL/SQL seguente, cambia l'oggetto directory Oracle MY_FILES con il tuo oggetto directory e cambia il nome del file con il file disponibile nella posizione della directory MY_FILES.

SET SERVEROUTPUT ON;

DECLARE
   i_image_type   VARCHAR2 (50);
BEGIN
   i_image_type := get_image_type ('MY_FILES', 'oracle-logo-gif-to-use.gif');

   IF i_image_type IN ('JPG', 'GIF', 'PNG')
   THEN
      DBMS_OUTPUT.put_line ('The file is a valid ' || i_image_type || ' image.');
   ELSE
      DBMS_OUTPUT.put_line (i_image_type);
   END IF;
END;
/

Uscita

The file is a valid GIF image.
PL/SQL procedure successfully completed.

Vedi anche:

• Come inserire un file in Oracle Table utilizzando PL/SQL?