Oracle PL/SQL:esporta dati da una tabella in CSV

Scopri come utilizzare il UTL_FILE pacchetto per esportare i dati da una tabella al file CSV in Oracle PL/SQL.

In Oracle, il pacchetto UTL_FILE contiene molte procedure e funzioni per scrivere un file di testo. Di seguito sono riportati i dettagli della sintassi e i passaggi necessari per scrivere un file:

Sintassi e passaggi per scrivere un file utilizzando UTL_FILE

-- Declare a variable to store file type
n_file UTL_FILE.FILE_TYPE;
-- Open the file in Begin section, it will open the file and return the file handle into the variable n_file
n_file := UTL_FILE.FOPEN('DIR_OBJ', 'YourCSVFileName.csv', 'w', 4000);
-- Write a single or multiple lines
UTL_FILE.PUT_LINE(n_file, 'abc, xyz, xxx');
-- Close the file
UTL_FILE.FCLOSE(n_file);

Esempio di base

Declare
   n_file Utl_File.File_Type;
Begin
   -- The directory object MY_DIR must be exist or create a new one
   n_file := Utl_File.Fopen('MY_DIR', 'myfile.csv', 'w', '4000');

   Utl_File.Put_Line(n_file, 'First line.');
   Utl_File.Put_Line(n_file, 'Second line.');
   Utl_File.Put_Line(n_file, 'Third line.');

   Utl_File.Fclose(n_file);
End;

Come accennato nell'esempio sopra, l'oggetto directory MY_DIR deve esistere. L'oggetto directory in Oracle è un riferimento alla directory fisica sul server. Quello che segue è un esempio di creazione di un oggetto directory in Oracle:

-- Windows example
CREATE OR REPLACE DIRECTORY CSVDIR AS 'd:\oracle\csvfiles';
-- Linux example
CREATE OR REPLACE DIRECTORY CSVDIR AS '/usr1/oracle/csvfiles';

Per ulteriori informazioni sull'oggetto directory in Oracle, controlla questo link.

Esporta dati da una tabella in CSV nell'esempio Oracle

Quello che segue è un esempio di stored procedure in Oracle, che esporterà i dati dalla tabella EMP in un file CSV:

Create Or Replace Procedure exp_emp_data Is

    n_file     utl_file.file_type;
    v_string   Varchar2(4000);
   
  -- get the data using cursor 
  Cursor c_emp Is
    Select
        empno,
        ename,
        deptno,
        sal,
        comm
    From
        emp;

Begin
    n_file := utl_file.fopen('CSVDIR', 'empdata.csv', 'w', 4000);

-- if you do not want heading then remove below two lines
    v_string := 'Emp Code, Emp Name, Dept, Salary, Commission';
    utl_file.put_line(n_file, v_string);
    
    -- open the cursor and concatenate fields using comma
    For cur In c_emp Loop
        v_string := cur.empno
                    || ','
                    || cur.ename
                    || ','
                    || cur.deptno
                    || ','
                    || cur.sal
                    || ','
                    || cur.comm;
        
        -- write each row
        utl_file.put_line(n_file, v_string);
    End Loop;
    
    -- close the file
    utl_file.fclose(n_file);
Exception
    When Others Then
        -- on error, close the file if open
        If utl_file.is_open(n_file) Then
            utl_file.fclose(n_file);
        End If;
End;

Ora la tua stored procedure è stata creata, eseguila per esportare i dati:

Begin
    exp_emp_data;
End;

Tutorial correlati:

• Utilità:genera procedura PL/SQL per esportare dati da una tabella