Ottimizzazione delle richieste ImageMagick simultanee utilizzando redis/php-resque

Il tuo comando in realtà si riduce a questo:

convert -size 600x400 xc:none                                 \
    \( 1.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 2.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 3.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 4.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 5.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 6.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    result.png

I miei pensieri sono i seguenti:

Punto 1:

Il primo -composite su una tela bianca sembra inutile, presumibilmente 1.png è un PNG 600x400 con trasparenza, quindi la tua prima riga può evitare l'operazione di composizione e risparmiare il 16% del tempo di elaborazione cambiando in:

convert -background none 1.png -fill ... -colorize 100% \
   \( 2.png ..
   \( 3.png ...

Punto 2

Ho inserito l'equivalente del tuo comando in un ciclo e ho eseguito 100 iterazioni e ci vogliono 15 secondi. Ho quindi modificato tutte le letture dei file PNG in letture di MPC file - o file Magick Pixel Cache. Ciò ha ridotto il tempo di elaborazione a poco meno di 10 secondi, ovvero del 33%. Una Magic Pixel Cache è solo un file pre-decompresso e pre-decodificato che può essere letto direttamente in memoria senza alcuno sforzo da parte della CPU. Puoi precrearli ogni volta che il tuo catalogo cambia e archiviarli insieme ai file PNG. Per crearne uno fai tu

convert image.png image.mpc

e otterrai image.mpc e image.cache . Quindi cambieresti semplicemente il tuo codice in modo che assomigli a questo:

convert -size 600x400 xc:none                                 \
    \( 1.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 2.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 3.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 4.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 5.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 6.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    result.png

Punto 3

Sfortunatamente non hai ancora risposto alle mie domande, ma se il tuo catalogo di risorse non è troppo grande, potresti metterlo (o gli equivalenti MPC sopra) su un disco RAM all'avvio del sistema.

Punto 4

Dovresti assolutamente correre in parallelo:ciò produrrà i guadagni più grandi di tutti. È molto semplice con GNU Parallel - esempio qui.

Se stai usando REDIS, in realtà è più facile di così. Solo LPUSH le tue immagini codificate MIME in un elenco REDIS come questo:

#!/usr/bin/perl
################################################################################
# generator.pl <number of images> <image size in bytes>
# Mark Setchell
# Base64 encodes and sends "images" of specified size to REDIS
################################################################################
use strict;
use warnings FATAL => 'all';
use Redis;
use MIME::Base64;
use Time::HiRes qw(time);

my $Debug=0;    # set to 1 for debug messages

my $nargs = $#ARGV + 1;
if ($nargs != 2) {
    print "Usage: generator.pl <number of images> <image size in bytes>\n";
    exit 1;
}

my $nimages=$ARGV[0];
my $imsize=$ARGV[1];

# Our "image"
my $image="x"x$imsize;

printf "DEBUG($$): images: $nimages, size: $imsize\n" if $Debug;

# Connection to REDIS
my $redis = Redis->new;
my $start=time;

for(my $i=0;$i<$nimages;$i++){
   my $encoded=encode_base64($image,'');
   $redis->rpush('images'=>$encoded);
   print "DEBUG($$): Sending image $i\n" if $Debug;
}
my $elapsed=time-$start;
printf "DEBUG($$): Sent $nimages images of $imsize bytes in %.3f seconds, %d images/s\n",$elapsed,int($nimages/$elapsed);

e quindi esegui più lavoratori che siedono tutti lì a fare BLPOP di lavori da fare

#!/usr/bin/perl
################################################################################
# worker.pl
# Mark Setchell
# Reads "images" from REDIS and uudecodes them as fast as possible
################################################################################
use strict;
use warnings FATAL => 'all';
use Redis;
use MIME::Base64;
use Time::HiRes qw(time);

my $Debug=0;    # set to 1 for debug messages
my $timeout=1;  # number of seconds to wait for an image
my $i=0;

# Connection to REDIS
my $redis = Redis->new;

my $start=time;

while(1){
   #my $encoded=encode_base64($image,'');
   my (undef,$encoded)=$redis->blpop('images',$timeout);
   last if !defined $encoded;
   my $image=decode_base64($encoded);
   my $l=length($image);
   $i++; 
   print "DEBUG($$): Received image:$i, $l bytes\n" if $Debug;
}

my $elapsed=time-$start-$timeout; # since we waited that long for the last one
printf "DEBUG($$): Received $i images in %.3f seconds, %d images/s\n",$elapsed,int($i/$elapsed);

Se eseguo un processo di generazione come sopra e lo faccio generare 100.000 immagini da 200 kB ciascuna e le leggo con 4 processi di lavoro sul mio iMac con specifiche ragionevoli, ci vogliono 59 secondi, o circa 1.700 immagini/s possono passare attraverso REDIS.