Come eseguire query sui ruoli dell'utente corrente

Non dovresti usare viste di compatibilità con le versioni precedenti deprecate ( cerca in questa pagina sysusers , per esempio ). Dovresti invece utilizzare sys.database_principals e sys.database_role_members . Tieni presente che alla connessione corrente potrebbe essere stato concesso l'accesso al di fuori dell'ambito del database (ad es. questi restituiranno risultati vuoti se l'utente è un sysadmin nel qual caso non è necessario che venga loro esplicitamente concessa l'appartenenza al ruolo o autorizzazioni specifiche). Anche per le autorizzazioni assegnate esplicitamente al di fuori dell'ambito di un ruolo, che sostituiranno quelle fornite dal ruolo, è inoltre necessario controllare sys.database_permissions . Ecco un esempio autonomo che puoi controllare (a patto che tu non abbia già un accesso chiamato blatfarA o un database chiamato floob ).

CREATE LOGIN blatfarA WITH PASSWORD = 'foo', CHECK_POLICY = OFF;
GO
CREATE DATABASE floob;
GO
USE floob;
GO
CREATE USER blatfarB FROM LOGIN [blatfarA] WITH DEFAULT_SCHEMA = dbo;
GO
GRANT SELECT, UPDATE ON SCHEMA::dbo TO blatfarB;
DENY INSERT, EXECUTE ON SCHEMA::dbo TO blatfarB;
GO
EXEC sp_addrolemember N'db_datareader', N'blatfarB'
GO

Per testarlo:

EXECUTE AS LOGIN = N'blatfarA';
GO

DECLARE @login NVARCHAR(256), @user NVARCHAR(256);

SELECT @login = login_name FROM sys.dm_exec_sessions WHERE session_id = @@SPID;

SELECT @user = d.name
  FROM sys.database_principals AS d
  INNER JOIN sys.server_principals AS s
  ON d.sid = s.sid
  WHERE s.name = @login;

SELECT u.name, r.name
  FROM sys.database_role_members AS m
  INNER JOIN sys.database_principals AS r
  ON m.role_principal_id = r.principal_id
  INNER JOIN sys.database_principals AS u
  ON u.principal_id = m.member_principal_id
  WHERE u.name = @user;

SELECT class_desc, major_id, permission_name, state_desc
  FROM sys.database_permissions
  WHERE grantee_principal_id = USER_ID(@user);

GO
REVERT;

Risultati:

name      name
--------  -------------
blatfarB  db_datareader

class_desc  major_id  permission_name  state_desc
----------  --------  ---------------  ----------
DATABASE    0         CONNECT          GRANT
SCHEMA      1         INSERT           DENY
SCHEMA      1         EXECUTE          DENY
SCHEMA      1         SELECT           GRANT
SCHEMA      1         UPDATE           GRANT

Pulisci:

USE master;
GO
ALTER DATABASE floob SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
GO
DROP DATABASE floob;
GO
DROP LOGIN blatfarA;
GO