SQL Server CTE:trova l'ID genitore superiore per ogni ID figlio?

Non puoi fare una cosa del genere?

;WITH cte AS (....)
SELECT
    * 
FROM 
    cte
CROSS APPLY 
    dbo.myTable tbl ON cte.XXX = tbl.XXX

Inserisci il CROSS APPLY dopo la definizione CTE - nell'unica istruzione SQL che fa riferimento al CTE. Non funzionerebbe??

OPPURE: - capovolgi la tua logica - esegui un CTE "top-down", che seleziona prima i nodi di livello superiore e quindi itera attraverso la gerarchia. In questo modo, puoi facilmente determinare il "padre di primo livello" nella prima parte del CTE ricorsivo, qualcosa del genere:

;WITH ChildParent AS
(
    SELECT
        ID,
        ParentID = ISNULL(ParentID, -1),
        SomeName, 
        PLevel = 1,   -- defines level, 1 = TOP, 2 = immediate child nodes etc.
        TopLevelFather = ID  -- define "top-level" parent node
    FROM dbo.[Agent_Agents] 
    WHERE ParentID IS NULL

    UNION ALL

    SELECT
        a.ID,
        ParentID = ISNULL(a.ParentID, -1),
        a.SomeName, 
        PLevel = cp.PLevel + 1,
        cp.TopLevelFather   -- keep selecting the same value for all child nodes
    FROM dbo.[Agent_Agents] a
    INNER JOIN ChildParent cp ON r.ParentID = cp.ID
)
SELECT  
   ID,
   ParentID,
   SomeName,
   PLevel,
   TopLevelFather   
FROM ChildParent

Questo ti darebbe nodi qualcosa del genere (basato sui tuoi dati di esempio, leggermente estesi):

ID  ParentID  SomeName      PLevel  TopLevelFather
20    -1      Top#20           1          20
 4    -1      TOP#4            1           4
 8    -1      TOP#8            1           8
 7     8      ChildID = 7      2           8
 3     7      ChildID = 3      3           8
 2     4      ChildID = 2      2           4
 9    20      ChildID = 9      2          20
 5     9      ChildID = 5      3          20
 1     5      ChildID = 1      4          20

Ora, se selezioni un particolare nodo figlio da questo output CTE, otterrai sempre tutte le informazioni di cui hai bisogno, incluso il "livello" del figlio e il suo nodo padre di primo livello.