Codifica classica ASP, MySQL o ODBC UTF8

Hai una possibilità per le lettere slovene secondo questa mappatura e un estratto dall'articolo wiki di Windows-1252 :

Ecco le cose da fare:

1. Utilizzare file codificati UTF-8 (senza BOM) contro la possibilità di contenere testo hardcoded. (✔ già fatto)

2. Specificare UTF-8 per il set di caratteri di risposta con ASP sul lato server o con meta tag sul lato client. (✔ già fatto)

3. Dì al server MySQL che i tuoi comandi sono in charset utf-8 e ti aspetti set di risultati codificati utf-8. Aggiungi un'istruzione iniziale alla stringa di connessione:...;stmt=SET NAMES 'utf8';...

4. Imposta Response.CodePage su 1252.

Ho testato il seguente script e funziona a meraviglia.

DDL: http://sqlfiddle.com/#!8/c2c35/1

ASP:

<%@Language=VBScript%>
<% 
Option Explicit

Response.CodePage = 1252
Response.LCID = 1060
Response.Charset = "utf-8"

Const adCmdText = 1, adVarChar = 200, adParamInput = 1, adLockOptimistic = 3

Dim Connection
Set Connection = Server.CreateObject("Adodb.Connection")
    Connection.Open "Driver={MySQL ODBC 3.51 Driver};Server=localhost;Database=myDb;User=myUsr;Password=myPwd;stmt=SET NAMES 'utf8';"
    
If Request.Form("name").Count = 1 And Len(Request.Form("name")) Then 'add new
    Dim rsAdd
    Set rsAdd = Server.CreateObject("Adodb.Recordset")
        rsAdd.Open "names", Connection, ,adLockOptimistic
        rsAdd.AddNew
        rsAdd("name").Value = Left(Request.Form("name"), 255)
        rsAdd.Update
        rsAdd.Close
    Set rsAdd = Nothing
End If

Dim Command
Set Command = Server.CreateObject("Adodb.Command")
    Command.CommandType = adCmdText
    Command.CommandText = "Select name From `names` Order By id Desc"
    
    If Request.QueryString("name").Count = 1 And Len(Request.QueryString("name")) Then
        Command.CommandText = "Select name From `names` Where name = ? Order By id Desc"
        Command.Parameters.Append Command.CreateParameter(, adVarChar, adParamInput, 255, Left(Request.QueryString("name"), 255))
    End If
    
    Set Command.ActiveConnection = Connection
    With Command.Execute
        While Not .Eof
            Response.Write "<a href=""?name=" & .Fields("name").Value & """>" & .Fields("name").Value & "</a><br />"
            .MoveNext
        Wend
        .Close
    End With
    
    Set Command.ActiveConnection = Nothing
    Set Command = Nothing
    
Connection.Close
%><hr />
<a href="?">SHOW ALL</a><hr />
<form method="post" action="<%=Request.ServerVariables("SCRIPT_NAME")%>">
Name : <input type="text" name="name" maxlength="255" /> <input type="submit" value="Add" />
</form>

Come ultima osservazione:

Quando è necessario applicare la codifica html alle stringhe recuperate dal database, non è più necessario utilizzare Server.HTMLEncode a causa di Response.Codepage è 1252 sul lato server e poiché Server.HTMLEncode è una codepage di contesto dipendente, ciò causerà output senza senso.
Quindi dovrai scrivere il tuo codificatore html per gestire il caso.

Function MyOwnHTMLEncode(ByVal str)
    str = Replace(str, "&", "&")
    str = Replace(str, "<", "&lt;")
    str = Replace(str, ">", "&gt;")
    str = Replace(str, """", "&quot;")
    MyOwnHTMLEncode = str
End Function
'Response.Write MyOwnHTMLEncode(rs("myfield").value)