Non puoi utilizzare una raccolta dichiarata localmente in una clausola SQL:
declare
type i_name is table of nvarchar2(512);
i_itemname i_name := i_name();
c number;
begin
select distinct owner bulk collect into i_itemname from all_objects;
dbms_output.put_line(i_itemname.count);
select count(*) into c
from all_tables
where owner in (select * from table(i_itemname));
dbms_output.put_line(c);
end;
/
where owner in (select * from table(i_itemname));
*
ERROR at line 10:
ORA-06550: line 10, column 41:
PLS-00642: local collection types not allowed in SQL statements
ORA-06550: line 10, column 35:
PL/SQL: ORA-22905: cannot access rows from a non-nested table item
ORA-06550: line 8, column 5:
PL/SQL: SQL Statement ignored
Ma puoi se è dichiarato a livello di schema, essenzialmente in modo che SQL conosca il tipo, non solo PL/SQL:
create type i_name is table of nvarchar2(512);
/
Type created.
declare
i_itemname i_name := i_name();
c number;
begin
select distinct owner bulk collect into i_itemname from all_objects;
dbms_output.put_line(i_itemname.count);
select count(*) into c from all_tables
where owner in (select * from table(i_itemname));
dbms_output.put_line(c);
end;
/
No errors.
18
128
PL/SQL procedure successfully completed.
Puoi anche unirti al table costruire piuttosto che usare una sottoquery:
...
select count(*) into c
from table(i_itemname) t
join all_tables at on at.owner = t.column_value;
...
Non sono del tutto chiaro cosa stai facendo però. (Se non stai utilizzando la raccolta per nient'altro, faresti meglio a unire i dati grezzi, ma presumo che la raccolta sia lì per un motivo).
Come menzionato da @haki nei commenti, puoi anche fare:
...
select count(*) into c
from all_tables
where owner member of (i_itemname);
...
... purché i_name e la colonna che stai confrontando con sono le stesse digita
. Nel mio esempio trova zero righe perché sto cercando di confrontare nvarchar2 con varchar2 , ma troverebbe una corrispondenza se ridefinito i_name come varchar2(512) . Nel tuo caso presumibilmente tab.col è nvarchar2 comunque.
