Un approccio consiste nell'usare Advanced Queuing di Oracle . A tale scopo è necessario impostare una coda (e una tabella di code) e scrivere una procedura PL/SQL che attenda il messaggio successivo nella coda.
Il lato C++ chiama quindi la procedura PL/SQL, che ritorna quando si è verificato l'evento successivo.
Sul lato Oracle, dovrai utilizzare DBMS_SCHEDULER o una struttura simile per creare l'evento , ovvero inserire un nuovo messaggio nella coda al momento opportuno.
È ancora un approccio di sondaggio. Tuttavia, non c'è assolutamente alcuna attività tra due eventi.
Aggiornamento:
Ecco un esempio di codice.
Configurazione iniziale della coda (il messaggio contiene un valore numerico e uno di testo):
grant AQ_ADMINISTRATOR_ROLE to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
CREATE TYPE sample_payload_type AS OBJECT
(
cmd VARCHAR2(20),
id NUMBER
);
BEGIN
DBMS_AQADM.CREATE_QUEUE_TABLE (
queue_table => 'sample_queue_table',
queue_payload_type => 'sample_payload_type',
sort_list => 'ENQ_TIME',
compatible => '10.0'
);
END;
/
BEGIN
DBMS_AQADM.CREATE_QUEUE (
queue_name => 'sample_queue',
queue_table => 'sample_queue_table'
);
DBMS_AQADM.START_QUEUE (
queue_name => 'sample_queue'
);
END;
/
Intestazione del pacchetto:
create or replace package sample_queue_pkg
as
procedure get_next_msg(
i_max_wait number
,o_cmd out varchar2
,o_id out number
);
procedure put_msg(
i_cmd varchar2
,i_id number
);
end sample_queue_pkg;
/
Corpo del pacchetto:
create or replace package body sample_queue_pkg
as
procedure get_next_msg(
i_max_wait number
,o_cmd out varchar2
,o_id out number
)
is
dequeue_options dbms_aq.dequeue_options_t;
message_properties dbms_aq.message_properties_t;
message_handle RAW(16);
message sample_payload_type;
NO_MESSAGE_RECEIVED EXCEPTION;
PRAGMA EXCEPTION_INIT(NO_MESSAGE_RECEIVED, -25228);
begin
dequeue_options.wait := i_max_wait;
DBMS_AQ.DEQUEUE (
queue_name => 'appuser.sample_queue',
dequeue_options => dequeue_options,
message_properties => message_properties,
payload => message,
msgid => message_handle
);
o_cmd := message.cmd;
o_id := message.id;
exception
when NO_MESSAGE_RECEIVED then
o_cmd := null;
o_id := null;
end get_next_msg;
procedure put_msg(
i_cmd varchar2
,i_id number
)
is
enqueue_options dbms_aq.enqueue_options_t;
message_properties dbms_aq.message_properties_t;
message_handle RAW(16);
message sample_payload_type;
message_id NUMBER;
begin
message := sample_payload_type(i_cmd, i_id);
DBMS_AQ.ENQUEUE(
queue_name => 'appuser.sample_queue',
enqueue_options => enqueue_options,
message_properties => message_properties,
payload => message,
msgid => message_handle
);
end put_msg;
end sample_queue_pkg;
/
Il server del database può inviare un messaggio utilizzando il seguente codice:
sample_queue_pkg.put_msg('run_task', 8234);
commit;
Il server C++ può attendere il messaggio (e riceverlo) chiamando il sample_queue_pkg.get_next_msg memorizzato . Il parametro i_max_wait specifica il tempo massimo di attesa per il messaggio successivo in secondi. Probabilmente vorrai implementare un ciclo che attende il messaggio successivo e lo elabora finché non riceve un segnale che il server sta per chiudersi.
