APEX_ZIP Esempio

In Oracle 12c in poi, su cui Oracle Apex è installato per impostazione predefinita, puoi utilizzare APEX_ZIP Pacchetto PL/SQL per comprimere i file. Quindi qui sto dando alcuni Oracle APEX_ZIP esempi:

Esempio Oracle APEX_ZIP

Il seguente codice PL/SQL ottiene i file (BLOB ) da una tabella e ziplo, e ti dà un BLOB finale che contiene tutti i file che hai aggiunto.

declare
   b_zip_file blob;

   cursor c_files
    is
    select file_name,
    file_content
    from emp_files
       where empno = 7894;

begin
   for c in c_files 
   loop
      -- adds the each blob to b_zip_file blob one by one
      apex_zip.add_file (
      p_zipped_blob => b_zip_file,
      p_file_name => c.file_name,
      p_content => c.file_content );
   end loop;

   -- finalizes the blob
   apex_zip.finish (
     p_zipped_blob => b_zip_file );

end;

Puoi vedere nel codice sopra che alla fine otterrai il BLOB finale che puoi ulteriormente memorizzare nella tabella o inviarlo a una procedura o scrivere un file sul server.

L'esempio seguente è un'aggiunta al codice precedente. Dopo aver compresso i file, scriverà il file zip sul server.

Comprimi i file utilizzando il pacchetto APEX_ZIP e scrivi sul server

Per scrivere il file sul server, è necessario un oggetto Oracle Directory. Di seguito è riportato un esempio, come creare un oggetto directory in Oracle che punta a una directory sul server.

Create or Replace directory my_dir as '/your/server/path';

Dopo aver creato la directory, puoi scrivere il file zip come mostrato nell'esempio seguente:

declare
   b_zip_file blob;

   -- variables for writing the files
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
   -- end variable declaration for file
   cursor c_files
    is
    select file_name,
    file_content
    from emp_files
       where empno = 7894;
begin
   for c in c_files 
   loop
      -- adds the each blob to b_zip_file blob one by one
      apex_zip.add_file (
      p_zipped_blob => b_zip_file,
      p_file_name => c.file_name,
      p_content => c.file_content );
   end loop;

   -- finalizes the blob
   apex_zip.finish (
     p_zipped_blob => b_zip_file );
   
   -- write the file
   l_blob_len := DBMS_LOB.getlength (b_zip_file);

   l_file :=
      UTL_FILE.fopen ('MY_DIR',
                     'my_zip.zip',
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP

      DBMS_LOB.read (b_zip_file,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
end;

Dopo aver eseguito il codice PL/SQL sopra, troverai il file my_zip.zip al MY_DIR percorso della directory sul server.

Esercitazioni correlate:

• Come ottenere BLOB da file in PL/SQL?
• Come decomprimere un file in PL/SQL?

Riferimento:

• Manuale Oracle APEX_ZIP