Come dividere una stringa in PL/SQL?

In questo articolo, sto fornendo un esempio di una funzione che utilizzo principalmente per dividere una stringa in PL/SQL. Soprattutto quando scrivo un programma per importare un file delimitato. Ecco quella funzione e un esempio di come usarla.

Funzione PL/SQL per dividere una stringa

Questa funzione accetta quattro parametri e i dettagli di questi parametri sono come sotto:

1. Stringa_origine :Stringa da dividere
2. Posizione_campo :Posizione del delimitatore
3. Non terminato :False per impostazione predefinita, ma se si passa True, verrà aggiunto il delimitatore specificato alla fine della stringa.
4. Delimitatore :L'impostazione predefinita è Virgola ',', puoi passare qualsiasi altro delimitatore.

CREATE OR REPLACE FUNCTION GetString (
Source_string IN VARCHAR2,
Field_position IN NUMBER,
UnTerminated IN BOOLEAN DEFAULT FALSE,
Delimiter IN VARCHAR2 DEFAULT ',')
RETURN VARCHAR2
IS
iPtrEnd PLS_INTEGER := 0;
iPtrStart PLS_INTEGER := 0;
vcSourceStrCopy VARCHAR2 (4000) := Source_string;
BEGIN
IF UnTerminated
THEN
vcSourceStrCopy := vcSourceStrCopy || Delimiter;
END IF;

IF Field_Position > 1
THEN
iPtrStart :=
INSTR (vcSourceStrCopy,
Delimiter,
1,
Field_Position - 1)
+ LENGTH (Delimiter);
ELSE
iPtrStart := 1;
END IF;

iPtrEnd :=
INSTR (vcSourceStrCopy,
Delimiter,
1,
Field_Position);
RETURN SUBSTR (vcSourceStrCopy, iPtrStart, (iPtrEnd - iPtrStart));
END GetString;

Esempio:utilizzare questa funzione nel programma PL/SQL

SET SERVEROUTPUT ON;

DECLARE
   v_string      VARCHAR2 (1000) := 'Java|.Net|C|Oracle|PHP';

   TYPE t_string IS TABLE OF VARCHAR2 (1000)
                       INDEX BY BINARY_INTEGER;

   t_str_array   t_string;
BEGIN
   FOR i IN 1 .. 5
   LOOP
      t_str_array (i) :=
         getstring (v_string,
                    i,
                    TRUE,
                    '|');
   END LOOP;

   FOR j IN t_str_array.FIRST .. t_str_array.LAST
   LOOP
      DBMS_OUTPUT.put_Line (t_str_array (j));
   END LOOP;
END;
/

Uscita:

Java
.Net
C
Oracle
PHP
PL/SQL procedure successfully completed.

Vedi anche:

• Esportare i dati in JSON utilizzando PL/SQL in Oracle 11g
• Programma PL/SQL per stampare i dettagli dei dipendenti