Perl e XPath:voci mancanti nella tabella del database

Hai già una spiegazione e una correzione, ma ti suggerisco le seguenti modifiche

• Dovresti prepare il INSERT INTO Istruzione SQL e quindi execute esso all'interno del ciclo. do ha un sovraccarico molto maggiore

• Il // ( descendant-or-self::node() ) Il costrutto XPath è costoso e dovresti riservarlo per i casi in cui non hai idea di dove si troverà l'elemento all'interno del documento, il che è molto raro. In questo caso il row1 gli elementi sono in /database/row1s/row1 e il row2 gli elementi sono in row2s/row2 rispetto a quello

• È molto più semplice utilizzare delimitatori diversi se si desidera utilizzare virgolette all'interno di una stringa tra virgolette. Ad esempio "My name is \"$name\"" è molto meglio come qq{My name is "$name"}

Ecco una versione del tuo programma che potrebbe aiutarti.

use strict;
use warnings;

use XML::XPath;
use DBI;

my $xp = XML::XPath->new( filename => 'animals4.xml' );

my $dbh = DBI->connect(
   'DBI:mysql:test', 'user', 'pw',
   { RaiseError => 1, PrintError => 0}
) or die "Fehler beim Verbidungsaufbau zum MariaDB-Server: $DBI::err -< $DBI::errstr\n";

my $insert_animal = $dbh->prepare('INSERT INTO animal4 (name, category, type, size) VALUES (?, ?, ?, ?)');

for my $row1 ( $xp->findnodes('/database/row1s/row1') ) {

   my $name     = $row1->getAttribute('name');
   my $category = $row1->getAttribute('category');

   printf qq{Level --- row1 "name" gives: $name\n};

   my @row2 = $xp->findnodes('row2s/row2', $row1);

   if ( @row2 ) {
      for my $row2 ( @row2 ) {

         my $type = $row2->getAttribute('type');
         my $size = $row2->getAttribute('size');

         print qq{Level row2 "type" gives: $type\n};
         print qq{Level row2 "size" gives: $size\n};

         $insert_animal->execute($name, $category, $type, $size);
      }
   }
   else {
      $insert_animal->execute($name, $category, undef, undef);
   }
}

produzione

Level --- row1 "name" gives: fox
Level row2 "type" gives: 1
Level row2 "size" gives: 10
Level row2 "type" gives: 2
Level row2 "size" gives: 8
Level --- row1 "name" gives: horse
Level row2 "type" gives: 3
Level row2 "size" gives: 100
Level --- row1 "name" gives: bee
Level --- row1 "name" gives: wasp