Oracle fornisce il modo per restituire più sottostringhe da una riga di stringa/clob che è stata analizzata?

Qualcosa del genere forse:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN sys.dbms_debug_vc2coll PIPELINED
IS  
  pos PLS_INTEGER;
  lastpos PLS_INTEGER;
  element varchar(2000);
BEGIN
   lastpos := 1;
   pos := instr(longline, ',');

   while pos > 0 loop
      element := substr(longline, lastpos, pos - lastpos);
      lastpos := pos + 1;
      pos := instr(longline, ',', lastpos);
      pipe row(element);
   end loop;

   if lastpos <= length(longline) then
      pipe row (substr(longline, lastpos));
   end if;

   RETURN;
END;  
/

Questo può essere utilizzato in questo modo:

SQL> select * from table(explode('1,2,3'));

COLUMN_VALUE
---------------------------------------------
1
2
3
SQL>

Se non sei su 11.x devi definire tu stesso il tipo di ritorno:

create type char_table as table of varchar(4000);

e cambia la dichiarazione della funzione in:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN char_table pipelined
.....