Non eseguire loop all'interno di loop in PL/SQL per questo:usa SQL per fornirti i dati pronti per l'uso.
Per prima cosa creiamo la tua tabella con alcuni dati di test (suppongo che i tipi di dati - li sostituisci con i tuoi) :
create table product_master (
product_no varchar2(10)
, product_holder varchar2(10)
, product_catalogue varchar2(10)
)
/
insert into product_master values ('1', 'SMITH', 'TEMP')
/
insert into product_master values ('2', 'SMITH', 'TEMP')
/
insert into product_master values ('3', 'HARRY', 'ARCH')
/
insert into product_master values ('4', 'TOM' , 'DEPL')
/
commit
/
Cosa vogliamo inviare a mail_send procedura per ogni product_holder è una raccolta (array) contenente product_no e product_catalogue . Quindi prima un tipo che contiene questi due elementi:
create type t_prod_cat_no as object (
product_no varchar2(10)
, product_catalogue varchar2(10)
)
/
E poi un tipo di tabella nidificata (tipo di raccolta) di quel tipo:
create type t_prod_cat_no_table as
table of t_prod_cat_no
/
La procedura mail_send quindi dovrebbe accettare il product_holder e il tipo di raccolta:
create or replace procedure mail_send (
p_parameter in varchar2
, p_product_holder in varchar2
, p_product_cats_nos in t_prod_cat_no_table
)
is
begin
dbms_output.put_line('-- BEGIN '||p_parameter||' --');
dbms_output.put_line('Dear '||p_product_holder);
dbms_output.put_line('Your products are:');
for i in 1..p_product_cats_nos.count loop
dbms_output.put_line(
'Catalogue: '||p_product_cats_nos(i).product_catalogue||
' - No: '||p_product_cats_nos(i).product_no
);
end loop;
end mail_send;
/
(Uso semplicemente dbms_output per simulare la creazione di una posta.)
Quindi puoi in SQL fare un group by product_holder e lascia che SQL generi la raccolta contenente i dati:
begin
for holder in (
select pm.product_holder
, cast(
collect(
t_prod_cat_no(pm.product_no,pm.product_catalogue)
order by pm.product_catalogue
, pm.product_no
) as t_prod_cat_no_table
) product_cats_nos
from product_master pm
group by pm.product_holder
order by pm.product_holder
) loop
mail_send(
'PRODMASTER'
, holder.product_holder
, holder.product_cats_nos
);
end loop;
end;
/
L'output del blocco precedente sarà:
-- BEGIN PRODMASTER --
Dear HARRY
Your products are:
Catalogue: ARCH - No: 3
-- BEGIN PRODMASTER --
Dear SMITH
Your products are:
Catalogue: TEMP - No: 1
Catalogue: TEMP - No: 2
-- BEGIN PRODMASTER --
Dear TOM
Your products are:
Catalogue: DEPL - No: 4
Farlo in SQL con un GROUP BY ti dà tutto in una singola chiamata da PL/SQL a SQL, che è molto più efficiente della prima chiamata per ottenere il set distinto di product_holder , passaci sopra e poi una chiamata per product_holder per ottenere i prodotti per ogni titolare.
AGGIORNAMENTO:
Aggiunto order by al collect funzione nel codice sopra per mostrare che hai il controllo sull'ordine in cui i dati vengono inseriti nella raccolta.
