Mascheramento dei dati Oracle

Questo problema è facilmente risolvibile in 12c con la funzione STANDARD_HASH .

La soluzione nelle versioni precedenti è solo leggermente più complicata. Crea un semplice wrapper attorno a DBMS_CRYPTO che agisca proprio come STANDARD_HASH:

--Imitation of the 12c function with the same name.
--Remember to drop this function when you upgrade!
create or replace function standard_hash(
    p_string varchar2,
    p_method varchar2 default 'SHA1'
) return varchar2 is
    v_method number;
    v_invalid_identifier exception;
    pragma exception_init(v_invalid_identifier, -904);
begin
    --Intentionally case-sensitive, just like the 12c version.
    if p_method = 'SHA1' then
        v_method := dbms_crypto.hash_sh1;
    --These algorithms are only available in 12c and above.
    $IF NOT DBMS_DB_VERSION.VER_LE_11 $THEN
        elsif p_method = 'SHA256' then
            v_method := dbms_crypto.hash_sh256;
        elsif p_method = 'SHA384' then
            v_method := dbms_crypto.hash_sh384;
        elsif p_method = 'SHA512' then
            v_method := dbms_crypto.hash_sh512;
    $END
    elsif p_method = 'MD5' then
        v_method := dbms_crypto.hash_md5;
    else
        raise v_invalid_identifier;
    end if;

    return rawToHex(dbms_crypto.hash(utl_raw.cast_to_raw(p_string), v_method));
end;
/

Potrebbe essere necessario accedere con SYS e concedere al tuo utente l'accesso a DBMS_CRYPTO per far funzionare la funzione:

grant execute on sys.dbms_crypto to <your_schema>;

Crea un sinonimo pubblico, concedilo a tutti e funziona esattamente allo stesso modo.

create public synonym standard_hash for <schema with function>.standard_hash;
grant execute on standard_hash to public;

select standard_hash('Some text', 'MD5') from dual;
    9DB5682A4D778CA2CB79580BDB67083F

select standard_hash('Some text', 'md5') from dual;
    ORA-00904: : invalid identifier

Ecco un semplice esempio di utilizzo della funzione:

update some_table
set column1 = standard_hash(column1),
    column2 = standard_hash(column2);

Ma l'aggiornamento di grandi quantità di dati può essere lento. Potrebbe essere più veloce creare una nuova tabella, eliminare quella vecchia, rinominare quella nuova, ecc. E il valore hash potrebbe essere maggiore della dimensione della colonna, potrebbe essere necessario alter table some_table modify column1 varchar2(40 byte);

Mi stupisce quanti prodotti e strumenti ci sono per fare una cosa così semplice.