Manipolazione delle raccolte

Almeno hai perso una definizione di tabella nel secondo caso. Questa affermazione:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

dichiara solo il tipo di oggetto (o record), non una tabella.

Quindi devi farlo in 2 passaggi:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Dopo di che hai bisogno di alcune correzioni di sintassi nello script:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

AGGIORNAMENTO

Soluzione sopra relativamente lenta a causa del gran numero di cambi di contesto. Ma il confronto di istanze di tipi di oggetti complessi non può essere eseguito direttamente in PL/SQL senza alcun lavoro aggiuntivo.
Per consentire a Oracle di sapere se le istanze di oggetti sono uguali o diverse, è necessario definire metodo di mappatura o ordinamento per tipo di oggetto . Entrambi i tipi di metodi non sono consentiti, quindi è necessario sceglierne uno appropriato. I metodi MAP funzionano più velocemente e nel nostro caso non è necessario ordinare, quindi provaci:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Attuazione:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Successivamente è possibile testare oggetti per l'uguaglianza nel codice PL/SQL come semplice varchar2 nel primo esempio dalla domanda:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/