Come controllare la versione del provider Oracle per ole-db. OraOLEDB.Provider Oracle

È possibile utilizzare ad esempio lo strumento RegDllView. Cerca "OraOLEDB", il risultato potrebbe essere questo:

Un approccio più semplice sarebbe quello di accedere al tuo ORACE_HOME\bin directory e individuare il file OraOLEDB??.dll . Verificare la versione con il tasto destro del mouse -> Proprietà -> Dettagli.

Tuttavia, ottieni solo la versione del file, ciò non significa necessariamente che anche questa DLL sia registrata e pronta per l'uso.

Oppure usa questo VBScript:

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

Il provider OLE DB può esistere a 32 bit e/o a 64 bit, quindi puoi eseguire lo script due volte:

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs