4 Esempi di blocchi anonimi PL/SQL

In questo tutorial, fornisco 4 esempi di blocchi anonimi PL/SQL, in modo che tu possa imparare come creare e utilizzare blocchi anonimi nel database Oracle. I blocchi anonimi in PL/SQL sono i programmi che non hanno alcuna istruzione Create Procedure o Create Function e non vengono salvati nel database Oracle. Blocchi anonimi PL/SQL utilizzati principalmente per il test o per eseguire il programma nel database Oracle solo per una volta.

1. Blocco anonimo PL/SQL per stampare i numeri in ordine inverso

Il seguente programma PL/SQL stamperà i numeri da 0 a 10 in ordine inverso, usando la clausola REVERSE nel ciclo for.

SET SERVEROUTPUT ON;
DECLARE
  counter   NUMBER;
BEGIN
  FOR counter IN REVERSE 0..10 LOOP
    DBMS_OUTPUT.PUT_LINE (counter);
  END LOOP;
END;
/

Uscita

10
9
8
7
6
5
4
3
2
1
0
PL/SQL procedure successfully completed.

2. Stampa il conteggio dei dipendenti in un reparto

Il seguente programma PL/SQL conteggerà i dipendenti nel reparto 90. La tabella è tratta dallo schema HR del database Oracle. Puoi scaricare questo schema dal seguente link Scarica schema HR.

SET SERVEROUTPUT ON;

DECLARE
   emp_count         NUMBER;
   v_department_id   NUMBER := 90;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = v_department_id;

   DBMS_OUTPUT.PUT_LINE(   'The employee count is: '
                        || emp_count
                        || ' for the department with an ID of: '
                        || v_department_id);
END;
/

Uscita

The employee count is: 3 for the department with an ID of: 90
PL/SQL procedure successfully completed.

3. Prendi input in PL/SQL Anonimo Blocca e stampa

Nell'esempio seguente, richiederà l'input dell'utente per l'ID reparto e stamperà il conteggio dei dipendenti in quel reparto e stamperà anche il nome del reparto.

SET SERVEROUTPUT ON;

DECLARE
   dept_id_var   NUMBER (4) := &department_id;
   dept_name     VARCHAR2 (30);
   emp_count     NUMBER;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = dept_id_var;

   SELECT department_name
     INTO dept_name
     FROM departments
    WHERE department_id = dept_id_var;

   DBMS_OUTPUT.PUT_LINE(   'There are '
                        || emp_count
                        || ' employees '
                        || 'in the '
                        || dept_name
                        || ' department.');
END;
/

Uscita

Enter value for department_id: 60
old   2:   dept_id_var  NUMBER(4) := &department_id;
new   2:   dept_id_var  NUMBER(4) := 60;
There are 4 employees in the IT department.

PL/SQL procedure successfully completed.

4. Blocco PL/SQL con <> Esempio

Il seguente blocco PL/SQL utilizza le etichette per il blocco padre e figlio. Il blocco figlio accederà alla variabile del blocco padre utilizzando il riferimento all'etichetta del blocco padre. Il programma aggiornerà il vecchio ID manager con il nuovo ID manager per i dipartimenti.

SET SERVEROUTPUT ON;
<<outer_block>>
DECLARE
   mgr_id       NUMBER (6) := '&current_manager_id';
   dept_count   NUMBER := 0;
BEGIN
   SELECT COUNT ( * )
     INTO dept_count
     FROM departments
    WHERE manager_id = outer_block.mgr_id;

   IF dept_count > 0
   THEN
     <<inner_block>>
      DECLARE
         dept_name   VARCHAR2 (30);
         mgr_id      NUMBER (6) := '&new_manager_id';
      BEGIN
         SELECT department_name
           INTO dept_name
           FROM departments
          WHERE manager_id = outer_block.mgr_id;

         UPDATE departments
            SET manager_id = inner_block.mgr_id
          WHERE manager_id = outer_block.mgr_id;

         DBMS_OUTPUT.PUT_LINE (
            'Department manager ID has been changed for ' || dept_name);
      END inner_block;
   ELSE
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
   END IF;
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
END outer_block;
/

Uscita

Enter value for current_manager_id: 100
old 3: mgr_id NUMBER (6) := '&current_manager_id';
new 3: mgr_id NUMBER (6) := '100';
Enter value for new_manager_id: 201
old 16: mgr_id NUMBER (6) := '&new_manager_id';
new 16: mgr_id NUMBER (6) := '201';
Department manager ID has been changed for Executive

PL/SQL procedure successfully completed.